*****************************************************************************
* mcmcsum help file
*
* Chris Charlton and George Leckie 
* Centre for Multilevel Modelling, 2011
*****************************************************************************

* Setup
use "http://www.bristol.ac.uk/cmm/media/runmlwin/tutorial.dta", clear

* Fit model using IGLS
runmlwin normexam cons standlrt, ///
	level2(school: cons) ///
	level1(student: cons) ///
	nopause

* Fit model using MCMC
runmlwin normexam cons standlrt, ///
	level2(school: cons) ///
	level1(student: cons) ///
	mcmc(on) initsprevious ///
	nopause

* Calculate and display MCMC summary statistics for all model parameters
mcmcsum

* Calculate and display  additional MCMC summary statistics for all model
* parameters
mcmcsum, detail

* Trajectory plots for all model parameters
mcmcsum, trajectories

* Kernel density plots for all model parameters
mcmcsum, densities

* Fiveway plot for the level 2 variance parameter ([RP2]var(cons))
mcmcsum [RP2]var(cons), fiveway

* Save the MCMC parameter chains from the current runmlwin model as
* variables in the current dataset
mcmcsum, getchains

* Compute the intraclass correlation (a non-linear combination of model
* parameters)
gen isc = RP2_var_cons_/(RP2_var_cons_ +  RP1_var_cons_)

* Calculate and display a variety of MCMC summary statistics for the
* derived ICC parameter
mcmcsum isc, variables

* Fiveway plot for the ICC parameter
mcmcsum isc, fiveway variables



*****************************************************************************
exit